udp_addresses.vhd

Go to the documentation of this file.

--**************************************************************
--*                                                            *
--*     The source code for the ATLAS BCM "AAA" FPGA is made   *
--*     available via the GNU General Public License (GPL)     *
--*     unless otherwise stated below.                         *
--*                                                            *
--*     In case of problems/questions/bug reports etc. please  *
--*     contact michael.niegl@cern.ch                          *
--*                                                            *
--**************************************************************

--**************************************************************
--*                                                            *
--*  $Source: /local/reps/bcmfpga/bcm_aaa/bcm_aaa/eth/udp_addresses.vhd,v $
--*  $Revision: 2.22.2.5 $                                         *
--*  $Name: dev $                                                 *
--*  $Author: mniegl $                                         *
--*  $Date: 2008/11/03 17:57:46 $                              *


--*                                                            *
--**************************************************************

--*****************************************************************--
--
--                      Ethernet Header
--
--*****************************************************************--


library ieee;

use ieee.std_logic_1164.all;

use ieee.std_logic_arith.all;

use ieee.std_logic_unsigned.all;

library work;

use work.main_components.all;

use work.ipmac.all;

use work.build_parameters.all;












































package udp_addresses is

--*******************************************************************************
--*                                   type defs
--*******************************************************************************

  type arp_pkt is record
    htype     : std_logic_vector(15 downto 0);
    ptype     : std_logic_vector(15 downto 0);
    hlen      : std_logic_vector(7 downto 0);
    plen      : std_logic_vector(7 downto 0);
    operation : std_logic_vector(15 downto 0);
    sha       : std_logic_vector(47 downto 0);
    spa       : std_logic_vector(31 downto 0);
    tha       : std_logic_vector(47 downto 0);
    tpa       : std_logic_vector(31 downto 0);
  end record;

--*******************************************************************************
--*                                   functions
--*******************************************************************************


  function reverse4byte (a       : std_logic_vector(31 downto 0)) return std_logic_vector;

  function reverse_any_vector(a  : std_logic_vector) return std_logic_vector;

  function cal_IP_chksum(a       : std_logic_vector) return std_logic_vector;

  function cal_UDP_chksum_base(a : std_logic_vector) return std_logic_vector;

  function conf_tdaqport (sel    : integer) return std_logic_vector;

  function conf_MAC (sel         : integer) return std_logic_vector;

  function conf_IP return std_logic_vector;

  function conf_chksum_rdy return std_logic_vector;

  function conf_chksum_ovr return std_logic_vector;

  function conf_chksum_start return std_logic_vector;

--*******************************************************************************
--*                                   constants
--*******************************************************************************

  alias zero_byte is gnd_vec;


  constant MAC_broadcast   : std_logic_vector(47 downto 0) := x"FF_FF_FF_FF_FF_FF";

  constant src_MAC_1       : std_logic_vector(47 downto 0) := conf_MAC(1);

  constant src_MAC_2       : std_logic_vector(47 downto 0) := conf_MAC(2);

  constant des_MAC         : std_logic_vector(47 downto 0) := MAC_sbcbcmtcc01;

  constant dcs_MAC         : std_logic_vector(47 downto 0) := MAC_pcatlbcmscs;

  constant tdaq_MAC        : std_logic_vector(47 downto 0) := MAC_sbcbcmtcc01;

  constant src_IP_addr     : std_logic_vector(31 downto 0) := conf_IP;

  constant dest_IP_addr    : std_logic_vector(31 downto 0) := ip_sbcbcmtcc01;

  constant rxsrcip         : std_logic_vector(31 downto 0) := dest_IP_addr;

  constant dcs_IP_addr     : std_logic_vector(31 downto 0) := ip_pcatlbcmscs;

  constant tdaq_IP_addr    : std_logic_vector(31 downto 0) := ip_sbcbcmtcc01;

  constant rxdestip        : std_logic_vector(31 downto 0) := src_IP_addr;

  constant src_port        : std_logic_vector(15 downto 0) := x"FFFF";

  constant std_port        : std_logic_vector(15 downto 0) := x"0FF0";

  constant dest_port       : std_logic_vector(15 downto 0) := conf_tdaqport(0);

  constant rxsrc_port      : std_logic_vector(15 downto 0) := x"FFFF";

  constant dcs_port        : std_logic_vector(15 downto 0) := x"FFF0";

  constant tdaq_port       : std_logic_vector(15 downto 0) := conf_tdaqport(1);

  constant rxdest_port     : std_logic_vector(15 downto 0) := x"FFFF";

  constant ethertype       : std_logic_vector(15 downto 0) := x"0800";

  constant arptype         : std_logic_vector(15 downto 0) := x"0806";

  constant udp_protocol    : std_logic_vector(7 downto 0)  := x"11";

  constant raw_protocol    : std_logic_vector(7 downto 0)  := x"FA";

  constant protocol        : std_logic_vector(7 downto 0)  := udp_protocol;

  constant IPV4            : std_logic_vector(3 downto 0)  := x"4";

  constant IHL             : std_logic_vector(3 downto 0)  := x"5";

  constant type_of_ser     : std_logic_vector(7 downto 0)  := zero_byte;

  constant realdatalen     : integer                       := 192;

  constant pktlen          : integer                       := realdatalen + 7;

  constant dcsdatalen      : integer                       := 212;

  constant tdaqdatalen     : integer                       := 141;

  constant ipheadlen       : integer                       := 20;

  constant udpheadlen      : integer                       := 8;

  constant udp_length      : std_logic_vector(15 downto 0) := conv_std_logic_vector(pktlen + udpheadlen, 16);

  constant tot_length      : std_logic_vector(15 downto 0) := conv_std_logic_vector(pktlen + udpheadlen + ipheadlen, 16);

  constant udp_dcs_length  : std_logic_vector(15 downto 0) := conv_std_logic_vector(dcsdatalen + udpheadlen, 16);

  constant tot_dcs_length  : std_logic_vector(15 downto 0) := conv_std_logic_vector(dcsdatalen + udpheadlen + ipheadlen, 16);

  constant udp_tdaq_length : std_logic_vector(15 downto 0) := conv_std_logic_vector(tdaqdatalen + udpheadlen, 16);

  constant tot_tdaq_length : std_logic_vector(15 downto 0) := conv_std_logic_vector(tdaqdatalen + udpheadlen + ipheadlen, 16);

  constant flags           : std_logic_vector(2 downto 0)  := "010";

  constant offset          : std_logic_vector(12 downto 0) := zero_byte & zero_byte(4 downto 0);

  constant TTL             : std_logic_vector(7 downto 0)  := x"FF";

  constant id              : std_logic_vector(15 downto 0) := x"0000";

  constant arp_ann_c       : arp_pkt :=
    (
      htype     => x"0001",
      ptype     => x"0800",
      hlen      => x"06",
      plen      => x"04",
      operation => x"0001",
      sha       => src_MAC_1,
      spa       => src_IP_addr,
      tha       => MAC_broadcast,
      tpa       => src_IP_addr
      );

  constant pause      : integer                       := 5000;

  constant cntwidth   : integer                       := 19;

  constant data       : std_logic_vector(15 downto 0) := x"f0f0";

  constant rd_rdy_pat : std_logic_vector(7 downto 0)  := x"10";

  constant rd_ovr_pat : std_logic_vector(7 downto 0)  := x"01";

  constant ip_chksum : std_logic_vector(15 downto 0) := cal_IP_chksum(IPV4 & IHL & type_of_ser &
                                                                      tot_length & id & flags & offset &
                                                                      TTL & protocol & x"0000" &
                                                                      src_IP_addr & dest_IP_addr);

  constant ip_chksum_dcs : std_logic_vector(15 downto 0) := cal_IP_chksum(IPV4 & IHL & type_of_ser &
                                                                          tot_dcs_length & id & flags & offset &
                                                                          TTL & protocol & x"0000" &
                                                                          src_IP_addr & dcs_IP_addr);

  constant ip_chksum_tdaq : std_logic_vector(15 downto 0) := cal_IP_chksum(IPV4 & IHL & type_of_ser &
                                                                           tot_tdaq_length & id & flags & offset &
                                                                           TTL & protocol & x"0000" &
                                                                           src_IP_addr & tdaq_IP_addr);

  constant udp_chksum_base : std_logic_vector(15 downto 0) := cal_UDP_chksum_base(src_IP_addr & dest_IP_addr &
                                                                                  zero_byte & protocol & udp_length &
                                                                                  src_port & dest_port & udp_length &
                                                                                  zero_byte & zero_byte);

  constant udp_chksum_base_dcs : std_logic_vector(15 downto 0) := cal_UDP_chksum_base(src_IP_addr & dcs_IP_addr &
                                                                                      zero_byte & protocol & udp_dcs_length &
                                                                                      src_port & dcs_port & udp_dcs_length &
                                                                                      zero_byte & zero_byte);

  constant udp_chksum_base_tdaq : std_logic_vector(15 downto 0) := cal_UDP_chksum_base(src_IP_addr & tdaq_IP_addr &
                                                                                       zero_byte & protocol & udp_tdaq_length &
                                                                                       src_port & tdaq_port & udp_tdaq_length &
                                                                                       zero_byte & zero_byte);

  constant start_chksum : std_logic_vector(15 downto 0) := conf_chksum_start;

  constant rdy_chksum   : std_logic_vector(15 downto 0) := conf_chksum_rdy;

  constant ovr_chksum   : std_logic_vector(15 downto 0) := conf_chksum_ovr;

end udp_addresses;

package body udp_addresses is

--*******************************************************************************
--*                                   functions
--*******************************************************************************

  function conf_chksum_start
    return std_logic_vector is
    variable p : std_logic_vector(15 downto 0) := (others => '0');
  begin
    if kRODconf = "0" then
      p := x"f9e8";
    elsif kRODconf = "1" then
      p := x"f9ed";
    end if;
    return p;
  end conf_chksum_start;

  function conf_chksum_rdy
    return std_logic_vector is
    variable p : std_logic_vector(15 downto 0) := (others => '0');
  begin
    if kRODconf = "0" then
      p := x"2f3e";
    elsif kRODconf = "1" then
      p := x"2f43";
    end if;
    return p;
  end conf_chksum_rdy;

  function conf_chksum_ovr
    return std_logic_vector is
    variable p : std_logic_vector(15 downto 0) := (others => '0');
  begin
    if kRODconf = "0" then
      p := x"d4e3";
    elsif kRODconf = "1" then
      p := x"d4e8";
    end if;
    return p;
  end conf_chksum_ovr;

  function conf_tdaqport(sel : integer)
    return std_logic_vector is
    variable p : std_logic_vector(15 downto 0);
  begin
    if kRODconf = "0" then
      if sel = 1 then
        p := std_port;
      else
        p := std_port+2;
      end if;
    elsif kRODconf = "1" then
      if sel = 1 then
        p := std_port + 1;
      else
        p := std_port+3;
      end if;
    end if;
    return p;
  end conf_tdaqport;

  function conf_MAC(sel : integer)
    return std_logic_vector is
    variable addr : std_logic_vector(47 downto 0);
  begin  -- conf_MAC
    if sel = 1 then
      if kRODconf = "0" then
        addr := testbeam_1;
      elsif kRODconf = "1" then
        addr := toronto_1;
      end if;
    elsif sel = 2 then
      if kRODconf = "0" then
        addr := testbeam_2;
      elsif kRODconf = "1" then
        addr := toronto_2;
      end if;
    end if;
    return addr;
  end conf_MAC;

  function conf_IP
    return std_logic_vector is
  begin  -- conf_IP
    if kRODconf = "0" then
      return ip_testbeam_1;
    elsif kRODconf = "1" then
      return ip_toronto_1;
    else
      return x"0000_0000";
    end if;
  end conf_IP;

  function reverse_any_vector (a : in std_logic_vector)
    return std_logic_vector is
    variable result : std_logic_vector(a'range);
    alias aa        : std_logic_vector(a'reverse_range) is a;
  begin
    for i in aa'range loop
      result(i) := aa(i);
    end loop;
    return result;
  end reverse_any_vector;

  function reverse4byte (a : in std_logic_vector(31 downto 0))
    return std_logic_vector is
    variable result : std_logic_vector(31 downto 0);
  begin
    result(31 downto 24) := a(7 downto 0);
    result(23 downto 16) := a(15 downto 8);
    result(15 downto 8)  := a(23 downto 16);
    result(7 downto 0)   := a(31 downto 24);
    return result;
  end reverse4byte;

  function cal_IP_chksum(a : std_logic_vector)
    return std_logic_vector is
    variable y                  : std_logic_vector(15 downto 0)  := (others => '0');
    variable input              : std_logic_vector(160 downto 1) := (others => '0');
    variable res, tmp, in1, in2 : std_logic_vector(31 downto 0)  := (others => '0');
  begin
    input       := (others => '0');
    if a'length <= 160 then
      input((a'length) downto 1) := a;
    else
      input := a(159 downto 0);
    end if;
    for i in 5 downto 1 loop
      in1 := x"0000" & input(32*i downto (32*i)-15);
      in2 := x"0000" & input((32*i)-16 downto (32*i)-31);
      tmp := in1 + in2;
      res := res + tmp;
    end loop;
    y := res(31 downto 16) + res(15 downto 0);
    return not y;
  end cal_IP_chksum;

  function cal_UDP_chksum_base (a : std_logic_vector)
    return std_logic_vector is
    variable y                  : std_logic_vector(15 downto 0)  := (others => '0');
    variable input              : std_logic_vector(160 downto 1) := (others => '0');
    variable res, tmp, in1, in2 : std_logic_vector(31 downto 0)  := (others => '0');
  begin
    input       := (others => '0');
    if a'length <= 160 then
      input((a'length) downto 1) := a;
    else
      input := a(159 downto 0);
    end if;
    for i in 5 downto 1 loop
      in1 := x"0000" & input(32*i downto (32*i)-15);
      in2 := x"0000" & input((32*i)-16 downto (32*i)-31);
      tmp := in1 + in2;
      res := res + tmp;
    end loop;
    y := res(31 downto 16) + res(15 downto 0);
    return y;
  end cal_UDP_chksum_base;

end udp_addresses;

---

Author: M.Niegl

Generated on Tue Nov 4 00:47:06 2008 for BCM-AAA by  1.5.7.1-20081012